
**Month-over-month-to-date growth**

Month-over-month-to-date growth compares a month-to-date at a specific date with the month-to-date at an equivalent date in the previous month.

 Sales PMTD uses [**DATEADD**](https://dax.guide/dateadd/?aff=dax-patterns) and filters the Date[DateWithSales] column to guarantee a fair comparison of the last period with data. Sales MOMTD and Sales MOMTD % rely on the Sales PMTD measure to guarantee the same fair comparison:

Sales PMTD :=

IF (

    [ShowValueForDates],

    CALCULATE (

        [Sales MTD],

        CALCULATETABLE (

            DATEADD ( 'Date'[Date], -1, MONTH ),

            'Date'[DateWithSales] = TRUE

        )

    )

)

Sales MOMTD :=

VAR ValueCurrentPeriod = [Sales MTD]

VAR ValuePreviousPeriod = [Sales PMTD]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod )

            && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales MOMTD % :=

DIVIDE (

    [Sales MOMTD],

    [Sales PMTD]

)